SUBROUTINE NCDFV(M,XN,CDF)
C     ----------------------------------------
C     SUBROUTINE NCDFV EVALUATES THE TAIL AREA
C         OF THE STANDARD NORMAL CURVE 
C             FROM X TO INFINITY
C     VARIABLES:
C           XN : INPUT ARRAY OF M X'S
C           CDF: OUTPUT ARRAY OF M CDFN'S
C     REFERENCE:
C         ALGORITHM AS66 APPL. STATIST.(1973)
C                VOL.22, PP.424 BY HILL   
C
C     availabel via the statlib archive, at http://lib.stat.cmu.edu/apstat/
C     and in Applied Statistics Algorithms, 
C     http://lib.stat.cmu.edu/griffiths-hill/
C     edited by Griffiths and Hill,
C     published by Wiley
C
C     LAST REVISION: 05-26-88 WCS
C     ----------------------------------------
      IMPLICIT DOUBLEPRECISION(A-H,O-Z)
C6    IMPLICIT REAL*8(A-H,O-Z)
      PARAMETER(CON=1.280D0,LTONE=7.0D0)    
C     -----------------------------------------
C     LTONE SHOULD BE SET TO THE VALUE AT WHICH
C     THE UPPER TAIL AREA BECOMES 1.0
C     IF A MACHINE PRODUCES N DECIMAL DIGITS IN
C     ITS REAL NUMBERS, THEN SET LTONE=(N+9)/3
C     FOR EXAMPLE, ON CRAY X-MP/28, SET LTONE=7
C     ON PYRAMID 90X, SET LTONE=8
C     -----------------------------------------
      DIMENSION XN(1152),CDF(1152),AH(7),BH(12)
      COMMON/LIST12/AH,BH
C
      DO 100 J=1,M
        Z= XN(J)
        I= 1
        IF ( Z .GE. 0.0D0 ) GOTO 20
        I= 0
        Z= -Z
C
 20     IF ( Z .LE. LTONE ) GOTO 40
          CDF(J)= 0.0D0
          GOTO 60
C
 40     Y= 0.50D0*Z*Z
        IF ( Z .LE. CON ) 
     &    CDF(J)= 0.50D0-Z*(AH(1)-AH(2)*Y/(Y+AH(3)-AH(4)
     &    /(Y+AH(5)+AH(6)/(Y+AH(7)))))
C
        IF ( Z .GT. CON )
     &    CDF(J)= BH(1)*DEXP(-Y)/(Z-BH(2)+BH(3)/(Z+BH(4)+BH(5)
     &    /(Z-BH(6)+BH(7)/(Z+BH(8)-BH(9)
     &    /(Z+BH(10)+BH(11)/(Z+BH(12)))))))
C
 60     IF ( I .EQ. 0 ) CDF(J)= 1.0D0-CDF(J)
C
 100  CONTINUE
C
      RETURN
      END
C