Phys 261 Hwk #8

Morin 3.70

For any problem we start with a force diagram, so let's add the ability to draw vectors:

Needs["VectorFieldPlots`"]

There is a tension, a weight and a normal.  We'll use a cylindrical coordinate system {r,θ,z},
where for drawing purpose our piece of paper is the r-hat,z-hat plane:

vecT = T{-Sin[θ],Cos[θ]}
vecN = N0 {Cos[θ],Sin[θ]}
vecG = m g {0,-1}

Choose parameters for illustration

params = {m->1,g->1,N0->1,T->1,θ->π/6}

And draw the diagram with all the vectors based at some common origin:

pt={0,0}

ListVectorFieldPlot[{{pt,vecT},{pt,vecN},{pt,vecG}}/.params]

To solve just about any problem we write F=ma:

FmaAssertion = m{-v^2/R,0}== vecN + vecG + vecT

Here we are solving

s= (Solve[FmaAssertion,{T,N0}]//Simplify)[[1]]

The sliding friction force is in the -θhat direction with magnitude f=μN0.  Since r[t]=R is constant, the F=ma component equation reads:

eqnv = m v'[t] == (-μ N0 /. s /. v->v[t])

This is a differential equation which can be solved by separating and integrating, or just DSolve:

sv = DSolve[{eqnv,v[0]==v0},v[t],t][[1]]

This seems messy, but most of the mess is just the constants.  Solving for the time at which v(t) vanishes:

st = Solve[(v[t]/.sv)==0,t][[1]]

As Morin says, kind of messy, but it checks out. If there is no friction, for example, it takes forever to stop:

Limit[(t/.st),μ->0]

Or if the "cone" is in fact a flat table (θ=π/2) when the normal force is just the good old mg independent of velocity,
so we constantly decelerate at μg, so the time to go from v0 to 0 is:

Limit[(t/.st),θ->π/2]

Morin 5.56

This one sort of belongs with the "Speedy Travel" from last week.  A planet of mass density ρ spins at ω.  How fast can it spin before
material flies off, e.g. at the equator?  That is, for what ω is the gravity force just large enough to keep material in orbit at R?
If m is a small piece of material at the equator, then we want that:

s=Solve[ - m ω^2 R == -G M m / R^2,ω]

Phrasing the answer in terms of ρ the period is then:

T = 2 π/ω /. s[[2]] /. M-> (4/3) π R^3 ρ

T0=Simplify[T,Assumptions->R>0]

Numerically, let's load up the constants we need:

Needs["PhysicalConstants`"]

T0/. {G->GravitationalConstant,ρ->EarthMass/((4/3)π EarthRadius^3)}/. {Newton->Kilogram Meter /Second^2}

Convert[5068.49 Second, Hour]

And oh yeah, this is exactly the time for speedy travel through the rabbit hole.

Morin 5.83

Consider a standard 2D elastic collision: initially particle one (M) is moving at v0 toward particle 2 (m at rest).
After a collision, particle 2 heads off at an angle θ while m1 goes at ϕ.
We are asked to find θ when the vertical component of particle 2's final state velocity is as large as it can be.

Thinking about it in the center of mass frame makes the problem easy.  First, observe that the CM is moving
purely in the x-direction, so the lab and CM frame agree on the y-direction velocities of a given object,
and in particular maximizing v2y in one frame will maximize in the other.  So how do we maximize v2y in the
CM frame?  By having the particles fly off  purely in the y-direction obviously.  So in the CM description, 
particle 2 comes in with velocity (-Vcm) in the x-direction, then scatters at the same speed (Vcm) in the y-direction.
In the lab frame then, the resulting velocity vector is (Vcm,Vcm), i.e. at angle π/4 relative to the x-axis.

Now let's solve this problem purely in the lab frame.  The conservation equations are:

eqnpx = M v0 == M v1 Cos[ϕ] + m v2 Cos[θ]

eqnpy = 0 == M v1 Sin[ϕ] - m v2 Sin[θ]

eqnK = M v0^2 == M v1^2 + m v2^2

Solving ...

s= FullSimplify[Solve[{eqnpx,eqnpy,eqnK},{v1,v2,ϕ}]]

which is messy enough, but taking out the solution we seek we define

v2y[θ_] = (v2/.s[[7]]) Sin[θ]

For what value of θ is this maximized?

Solve[v2y'[θ]==0,θ]

Oh yeah, that becomes obvious e.g. when one remembers trig ID's such as

TrigExpand[Sin[2 θ]]

and then notes that Sin[2 θ] is maximized when 2θ = π/2.  Note that maximal v2y is then:

v2y[π/4]

which just happens to be the center of mass velocity.

Morin 5.89

A plate of mass M moves at v.  A mass m is dropped on the plate and skids to rest relative to the plate.
How much energy must be pumped in to the system to make the plate (together with mass m) move again at v?

Well, there are no external forces (frictionless table) so momentum is conserved in the plate/pea collision, and the
new speed is given by:

s=Solve[M v == (M+m) vnew,vnew]

That means that we have kinetic energy

Knew = (1/2) (M+m) (vnew)^2 /. s[[1]]

And if we want to end up in a state with both M and m moving at the original v we must supply an energy

ΔK = (1/2) (M+m) v^2 - Knew //Simplify

Notice that when M is large this becomes:

Limit[ΔK,M->Infinity]

The "intuitive" explanation is that from beginning to end the plate is in the same state, but we have added the energy 
necessary to bring mass m from speed 0 up to v (i.e (1/2) m v^2), AND we've replaced the energy lost to heat in
the scraping, sliding, stopping process as the little mass interacts with the plate.  In the limit that M is large, let's view
that process in the CM frame (i.e. the plate frame).  In that frame, the little m lands with relative velocity v, then
skids to a stop, losing *all* of its kinetic energy.  Thus (1/2) m v^2 is lost to heat, and altogether our energy bill is mv^2.

Morin 5.94

An essentially massless dustpan starts from rest at the top of a incline (parameterized by the angle θ).
Along the ramp there is a layer of dust with density σ kg/meter.  The dustpan slides (frictionlessly) down
the hill, sweeping up the dust along the way.  We see the motion x(t) where x is the distance from the start.

We derive the differential equation in the usual Δt way:  at time t we have a dustpan of mass m(t) = σ x(t)
(that being the amount of dust which has been swept up so far) colliding with an amount Δm of dust at rest.
If we are moving at v(t) = x'(t), the amount of dust we are about to pick up in Δt is σ Δx = σ v Δt.
After the collision, both dustpan and dust continue on at v+Δv.  Thus the change in momentum is:

Δp = (m + Δm)(v+Δv) - m v

Dividing by Δt we get

(Δp/Δt) /. {m->σ x[t], Δm -> σ x'[t] Δt, v->x'[t], Δv->x''[t]Δt}//Simplify

Limit[%,Δt->0]

Equating with the external force (which is m g Sin[θ], or m gθ for short) the σ's cancel and we get our equation of motion:

eqn = x''[t]  == gθ -(x'[t])^2/x[t]

With fingers crossed we ask for:

s =DSolve[eqn,x[t],t]

Obviously we got both more and less than we bargained for.
How do we solve this one "by hand"?!
The argument runs backward from the answer: we ask "what could x(t) look like"?
We have the following building blocks from which to build an expression for x(t):  t, g, θ, σ.
Given the physical dimensions, we observe that the answer for x(t) cannot involve σ, 
since it is the only parameter which has kilograms in its units, and there is nothing to cancel
those in an expression which must end up with dimensions of meters.  This "explains" why
the σ's cancelled out of our differential equation.  Then from the rest the only expression with
units of distance is: g t^2.  Thus x(t) = f(θ) g t^2 where all that remains is to find the dimensionless constant.
So we try the ansatz x(t) = (1/2) a t^2:

eqn /. {x->Function[{t},(1/2) a t^2]}

Solve[%,a]

In other words, the acceleration is constant and equal to (1/3) g Sin[θ].
As a last check:

eqn /. {x->Function[{t},(1/6) gθ t^2]}