Morin 3.53

Morin 3.53 asks us to fire a projectile with intial speed v0 at angle θ, including the effects both of gravity and of air resistance, and to find the angle θ which makes the peak height occur as far as possible downrange.
To start, we find the motion for the given initial conditions.

sx=DSolve[{x''[t]== - α x'[t], x'[0]== v0 Cos[θ],x[0]==0},x[t],t][[1]]

sy=DSolve[{y''[t]== - α y'[t] -g, y'[0]== v0 Sin[θ],y[0]==0},y[t],t][[1]]

Let's pick some numerical values for illustration, and draw the trajectory.  Let's use a "rule" to do this:

params = {g->9.8,v0->50,α->.1,θ->π/3}

ParametricPlot[{x[t]/.sx,y[t]/.sy}/.params, {t,0,7.7}]

To simplify the algebra for us, Morin specifies α in the following peculiar way:
assume that the drag force at time t=0 has magnitude mg, i.e. that α v0 = g. 
Defining another substitution rule,

αrule = α -> g/v0

... we then ask for the time at which we peak, i.e. when y[t] is a maximum:

peakeqn =( D[y[t]/. sy,t]==0//Simplify)

st = Solve[peakeqn,t][[1]]

Given that solution for t, we next ask for the x-range as we peak:

d = x[t]/.sx/.st //Simplify

And folding in the special value of α in this problem:

d = x[t]/.sx/.st /.αrule//Simplify

Since we have Mathematica, we can just ask for the optimal angle as:

θrule = Solve[D[d,θ]==0,θ]

We of course want the real positive angle with this Cos and Sin:

{Cos[θ],Sin[θ]}/.θrule[[2]]//Simplify

If we were doing the algebra for this problem "by hand", we might do this last step by defining a
variable β=Sin[θ], in which case we need to optimize the function

f[β_] = Sqrt[1-β^2]β/(1+β)

(That's the expression for d with constants taken out and Cos expressed in terms of Sin.)
Then the equation we need to solve boils down to a quadratic:

βeqn = (f'[β]==0//Simplify)

βsoln =Solve[βeqn]

And we recognize the root we want as the inverse of the Golden ratio:

(β/.βsoln[[2]]) ==1/GoldenRatio

The result above agrees, of course:

(Sqrt[(1/2) (3-(Sqrt[5]))])//FullSimplify

%*GoldenRatio//Simplify