Morin 9.23

A coin of radius r and mass m rolls w/o slipping in a circle of radius R (that's the circle of
points it touches on the ground).  Using  the usual cylindrical r,θ,z coordinates, and choosing
our origin at the center of circle on the ground, the CM is to be found at:

rcm = {R,0,0}+r{-Cos[θ],0,Sin[θ]}

As usual, be wary of the overuse of the symbol θ---the θ here is the tilt angle of the coin where θ=π/2
is standing straight on edge.
The goal is to find the angular speed Ω as it traces out it circle.
The spin due to that motion is described by:

Ωvec = {0,0,Ω}

The overall strategy will be to write down the relationships from F=ma and (d/dt) L=τ, and then
boil them down to find Ω.  This should work, since there are 3 unknowns as we start
(two components of force from contact at the ground and Ω),  and three nontrivial relationships
(the r and z components of F=ma, and the torque equation).  In fact, now that we think about it,
since the CM at constant height, the z-component of F=ma tells us that the  "unknown" normal
force on the ground must be exactly mg in this problem.  And r-component tells us that the 
friction force must be just the right size for going in a circle of appropriate radius.
But if we choose an origin on the ground, that force gives no torque, so we can avoid
having to explicitly write down that force. All we need is the torque equation.

To get there, we first construct the center of mass velocity and orbital angular momentum.
Note that the CM moves in a circle of size R less a little bit with angular speed Ω:

vcm = {0,Ω rcm[[1]],0}

Lorb = m Cross[rcm,vcm]//Simplify

To get the rest of L we need to deal with spin.  Defining the "nice" basis vectors
which point in the principal directions, e3 will point out through the face of the coin,
and e2 will point through the diameter:

e3 = {Sin[θ],0,Cos[θ]}

e2 = {-Cos[θ],0,Sin[θ]}

The piece of spin from rolling is then some ωs (in the -e3 direction as we define things),
and the total spin is that plus the once-per-orbit twisting piece:

ωvec = -ωs e3 + Ωvec

Now comes the crux of the whole matter.  We decompose this spin into its components
in the "nice" directions (by taking dot products with the basis vectors) and then scale these
spin components by the appropriate moments of inertia (which we call I2 and I3 for now):

Lspin = I2 Dot[ωvec,e2]e2 + I3 Dot[ωvec,e3] e3//Simplify

So now we have the total L:

Lvec = Lorb + Lspin//Simplify

Of course we will take d/dt, where the only thing which depends on time here is the rhat basis
vector.  Since d/dt rhat is Ω θhat we just extract Lr and multiply by Ω, and equate with the torque
appropriate for our origin.  Again, the radial force doesn't appear here, and since N=mg we end up
with the following master equation:

τeqn = Lvec[[1]] * Ω == - m g r Cos[θ]

Finally fold in various other bits of information, such as the precise values of I2 and I3,
as well as our knowledge of ωs from the rolling w/o slipping condition:

τeqn2=(τeqn /. {I2 -> (1/4) m r^2, I3->(1/2) m r^2, ωs->Ω R/r})//Simplify

This obviously gives us Ω^2, but since we can't "Solve" for Ω^2 let's finess the point by 
defining a variable Ω2 (by which we mean Ω^2 of course):

τeqn3 = τeqn2/. Ω^2 -> Ω2

Solve[τeqn3,Ω2]//Simplify

And then the last point to note is that since Ω2 is positive there is a condition which the inputs
R, r and θ must obey in order for the motion described to exist, namely that  6R > 5 r Cos[θ].

Your job: apply the same techniques to, say, a tilted stick whirling around a circle, or to another
tilted coin which has a handle pivoted at the origin.