Relativity

A couple of the problems this week involve relativistic addition of velocity
Here are some incantations to derive the relevant formulae.
First define a 4 component vector which gives the coordinates of an event:
Today the train gets the unprimed coordinates:

$Post=MatrixForm

eventTrain = {t,x,y,z}

Here is the Lorentz transformation to go to a frame moving down the x-axis at -β

Λ = {{γ,β γ,0,0},{β γ, γ,0,0},{0,0,1,0},{0,0,0,1}}

eventGround = Λ.eventTrain

Here is a function to form the interval, i.e. the “4-length” (squared) of our Mikowski space “4-vector”.

MinkLSq[a_] := a[[1]]*a[[1]] - a[[2]]*a[[2]]-a[[3]]*a[[3]]-a[[4]]*a[[4]]

Which can be used as we show that the interval between "0" and "event" is the same in both frames.
In terms of the train coordinates, the interval (squared) is:

ITrain = MinkLSq[eventTrain]

In terms of ground-based coordinates,

IGround = MinkLSq[eventGround]

And this is the same thing, once we put in the information about γ:

γrule = γ->1/Sqrt[1-β^2]

IGround/.γrule

Simplify[%]

Now consider "0" to be an event where a baseball is thrown down the x-axis at "ux" relative to the train,
and let event "A" be the catching event a moment later.
If the time in the air (per train frame)  is T, then the train’s coordinates for event A are:

eventAtrain = {T,ux T, 0,0}

which leads to these coordinates in the ground frame

eventAground = Λ.eventAtrain

The velocity of the baseball relative to the ground has x-component given by distance over time as usual:

uxGround = eventAground[[2]]/eventAground[[1]]

Simplify[%]

Your jobs: 
  - go back and add a nonzero component "uy" to the baseball's velocity (in the
    train frame) and find the x and y components of velocity relative to the ground. 
  - then suppose the “baseball” is in fact a photon with velocity components
    ux = 1*Cos[θ] and uy = 1*Sin[θ] relative to the train.  Verify that the photon speed
    is c=1 in the ground frame too, i.e. that this proposition is True:

proposition = (uxGround)^2 + (uyGround)^2 == 1

$Post=.

Series Stuff

BTM 4.2.5 asks about the convergence of the series

f[n_] = 1/Sqrt[3 n^4 + 6 n^3+98]

First let's just look at the terms we summing:

ListPlot[Table[f[n],{n,2,40}]]

And the partial sums:

ListPlot[Table[Sum[f[n],{n,2,m}],{m,2,50}]]

So this one might converge. Can we prove it for sure?

Per standard protocol, let's try the ratio test:

r[n_] := f[n+1]/f[n]

Limit[r[n],n->Infinity]

Did that decide it?
If not, on to the integral test: (this is a handy place to tell you that to abort an evaluation you can type Alt-. )

Integrate[f[n],{n,2,L}]

So how *do* you do this one?!  Perhaps a comparison with e.g. 1/(2 n^2):

Plot[{f[n],1/(2 n^2)},{n,2,50}]

Here is another informative view:

Plot[{f[n]-1/(2 n^2)},{n,2,50}]

Your job: repeat the above for these f[n]'s:

f[n_] = Exp[n]/(Exp[4 n]+5)

f[n_] = Sech[n]

f[n_] = 1/(n^2 Log[n])

More Series Stuff

If you ever need the series for a function, you know how to find it, right?!  Here’s an important one:

Series[Exp[x],{x,0,20}]

Here is some random function:

f[x_] = Cos[x]/(1+Sin[x])

Here is an incantation to create the Taylor series truncated to polynomials of various degrees.

Do[p[x_,n]=(Normal[Series[f[q],{q,0,n}]]/.q->x),{n,0,20}]

Plot[{f[x],p[x,0],p[x,1],p[x,2]},{x,-1,1}]

Your job: 
  - change the degree and observe how the agreement improves
  - expand the x-range of the graph and observe a problem at π/2

And if there are relationships between functions, then there must be relationships among the terms in the series.  Let's verify Exp[a]*Exp[b]==Exp[a+b] in the language of series to, say order 5:

polyA = Normal[Series[Exp[a],{a,0,5}]]

(The Normal just chops off the "Order" symbol.)

polyB = Normal[Series[Exp[b],{b,0,5}]]

The product of these two polynomials is:

polyAB = (polyA*polyB//Expand)

How does that compare with the series for Exp[a+b]?

polyC = Normal[Series[Exp[x],{x,0,5}]]/.x->a+b

Here is  quick way to that the algebra works:

Factor[polyAB]

Or if we know there is supposed to be an identity which says: Sinh[x+y] = what was that again?!
Oh yeah:

TrigExpand[Sinh[x+y]]

For the case x=y, we want to check that the series

seriesCosh = Series[Cosh[x],{x,0,5}]

seriesSinh = Series[Sinh[x],{x,0,5}]

does in fact equal the series:

seriesSinh2 = Series[Sinh[2x],{x,0,5}]

So is the proposition true?!

proposition = seriesSinh2 == 2 seriesSinh*seriesCosh

Your job: repeat for the case of the homework, showing that (1+x)^p (1+x)^q does equal (1+x)^(p+q).  You are supposed to work out the x^3 terms "by hand" for the homework, but feel free to print the cell as a reference to check yourself.  Here is a start:

PolyP = Series[(1+x)^p,{x,0,3}]