Complex Stuff

Here are a couple of random complex numbers:

z1 = (Sqrt[2]+I)/(1-I)

z2 = (1+I)/Sqrt[2]

Ask yourself what the norms of the numbers are before you evaluate these cells:

z1*Conjugate[z1]//Simplify

Norm[z1]

Norm[z2]

z1*z2

Norm[z1*z2]

And of course in BTM 5.2.7 you are asked to verify that

Norm[z1+z2] ≤ Norm[z1]+Norm[z2]

More generally, in BTM 5.2.6 you are asked to show once and for all that for generic z1 and z2, the following are true:

z1= x1 + I y1
z2 = x2 + I y2
prop32 = Norm[z1+z2]≤ Norm[z1]+Norm[z2]

BTW this is one case where the amazing Mathematica seems to fall flat.
You and and can prove this statement is exactly True by squaring both sides:

FullSimplify[prop32,Assumptions->Element[{x1,x2,y1,y2},Reals]]

But surely Mathematica can figure this one out:

Norm[z1*z2] == Norm[z1]*Norm[z2]

FullSimplify[%,Assumptions->Element[{x1,x2,y1,y2},Reals]]

Nope?! Well who needs the built-in Norm.  We’ll roll our own:

myNorm[z_] := Sqrt[(Re[z])^2 + (Im[z])^2]
prop = myNorm[z1*z2] == myNorm[z1]*myNorm[z2]
FullSimplify[prop,Assumptions->Element[{x1,x2,y1,y2},Reals]]

And here is the series homework in one cell, showing that if functions are related by differentiation/integration, then their series are related too:

s1 =Series[1/(1+x^2),{x,0,10}]
q=Integrate[1/(1+x^2),x]
s2 = Series[q,{x,0,11}]
s3 = Integrate[s1,x]

Lastly, make sure you understand this one, where series and complex numbers collide:

z= Exp[I θ]
Series[z,{θ,0,11}]

ComplexExpand[z]

And thought the Norm function doesn’t know it, these numbers always have length 1:

z*Conjugate[z]//Simplify[#,Assumptions->Element[θ,Reals]]&

Relativity Stuff

Here is the discussion from class this week:

$Post = MatrixForm

z=.

An object traces out a worldline.  In terms of a clock attached to it, we could write the curve in *our* frame as

r[τ_] := {t[τ],x[τ],y[τ],z[τ]}

and take d/dτ to get 4-vectors.
But typically we choose to work in our own "fixed" coordinate system and write:

r[t_] := {t,x[t],y[t],z[t]}

r[t]

Then we take d/dτ = d/d(t/γ) = γ d/dt, where the gamma factor is:

γ[v_] = 1/Sqrt[1-v^2]

Assuming for simplicity that the velocity is purely in the x-direction at the moment,
i.e. that y'[t]=0=z'[t] at the moment we are considering

v[t_] = γ[x'[t]]D[r[t],t]

And taking one more derivative the 4-acceleration is:

a[t_] = γ[x'[t]] D[v[t],t]//Simplify

Let’s agree to work in the frame where the y and z velocities are momentarily zero, i.e. we choose our x-axis to align with the velocity vector at time t.

genericA =Simplify[%,Assumptions->{y'[t]==0,z'[t]==0}]

Morin 13.4 asks about constant *proper* acceleration.  That is, in the co-moving frame (the inertial frame coasting at a velocity which just happens to be v[t]) the 4-acceleration is just (0,g,0,0).

rocketA = {0,g,0,0}

To connect to the lab - frame version we need the Lorentz boost matrix :

Λ = {{γ,β γ,0,0},{β γ,γ,0,0},{0,0,1,0},{0,0,0,1}}

Folding in what we know about β and γ:

Λ.rocketA
labA = % //. {γ->γ[β],β->x'[t]}

So the x[t] for a constant (proper) acceleration is the solution to:

MatrixForm[labA] == MatrixForm[genericA]

Note that the first two equations say the same thing, after dividing out by x’[t].
Homework problem Morin 13.6 asks you to do the steps above, and to note that the result that

de = x''[t] == g /γ^3

is exactly what Morin equation 13.26 says.
To get the motion when we start from rest at x=0, we DSolve:

DSolve[{de/.γ->1/Sqrt[1-x'[t]^2],x[0]==0,x'[0]==0},x[t],t]

We’ll take the 2nd solution if we are accelerating down the positive x-axis.

Alternatively, we arrive at the same place starting with the idea of relativistic velocity addition.
In terms of ship-board time τ, a co-moving observer says that between times τ and τ+dτ
the rocket accelerates from u=0 to u=g*dτ.  A ground-based observer (who deems the co-mover
to have speed v[τ]) then says the new speed is given by the relativistic “super-plus” formula:

Clear["Global`v"]
veqn = v[τ+dτ] ==(v[τ] + g dτ) /(1+ v[τ] g dτ)

To get a differential equation we expand in powers of the tiny dτ.
Note how Series is happy to thread both sides of the equation:

Series[veqn,{dτ,0,1}]

de = Normal[%]//Simplify

Starting from rest we solve for v[τ], the velocity as expressed in terms of ship-board time.

soln=DSolve[{de,v[0]==0},v[τ],τ]

If you kick Mathematica it recognizes that function:

FullSimplify[soln]

Or in short: the “rapidity” at time τ is just the naive “velocity” gτ.
To translate back to *our* time, note that dt/dτ = γ[τ] = Cosh[g τ],
so when we integrate boths sides dτ:

t[τ_] = (Integrate[Cosh[g τ],τ])

The inverse relationship which expresses τ in terms of our ground based t is then

τ[t_] = ArcSinh[g t]/g

BTW the ArcSinh can be writtin in this form, if you like:

f[t_] =Log[Sqrt[1+t^2]+t]

f[t] == ArcSinh[t]//FullSimplify

Plot[{f[t],ArcSinh[t]},{t,-10,10}]

Which explains where the Sqrt comes from as we express the v[τ] in terms of our t:

v[t_] = Tanh[ArcSinh[g t]]//Simplify

Does this integrate up to the same x[t] we found above using 4-acceleration?  (DRUM ROLL)

x[t_] = (Integrate[v[tp],{tp,0,t},Assumptions->{t>0,g>0}])

So now we can make a plot of the worldline:

p={g->1}

ParametricPlot[{x[t],t}/.p,{t,0,1},AspectRatio->1,PlotRange->{{0,1},{0,1}}]

Relativistic Collisions/Decays using 4-momentum

Any process conserves energy and momentum.
The 4-momentum idea is to put the equations together in a vector, and occasionally
be inspired to consider lengths and other dot-products to short-cut through the algebra.

e.g. Particle A decays to B+C:

p=.

p4A = {mA,0,0,0}

p4B = {EB,p,0,0}

p4C = {EC,-p,0,0}

Solve[mA == Sqrt[p^2+mB^2]+Sqrt[p^2+mC^2],p]//Simplify

Sqrt[mB^2+p^2]/.%[[1]]

Simplify[%,Assumptions->{mA>0,mB>0,mC>0}]

Or use 4-vectors to write:

Ldot[a_,b_]:= a[[1]]*b[[1]] - a[[2]]*b[[2]] - a[[4]]*b[[4]] - a[[4]]*b[[4]]

Ldot[p4A,p4B]