Here is the good old simple harmonic oscillator, whose solution is sometimes written as a sum of sines and cosines.

sho = θ''[t]+ ω0^2 θ[t]==0

s=DSolve[sho,θ[t],t]

ϕ[t_] = θ[t]/.s[[1]]

If you like, these can be traded for Exp(iθ):

TrigToExp[ϕ[t]]

And BTW the inverse trig functions can be likewise be expressed in terms of the inverse of Exp:

TrigToExp[ArcSin[x]]

One new wrinkle on the oscillator this week is that we add damping:

de = x''[t] + 2 γ x'[t] + ω0^2 x[t] ==0
DSolve[de,x[t],t]

Note the generic solution is phrased in terms exponentials, with two basic solutions.
Depending on parameter choices you get either two decaying exponentials (overdamped)
or sines and cosines times a decaying exp (underdamped case):

pOver= {ω0->1,γ->4}
sOver = DSolve[{de,x[0]==1,x'[0]==0}/.pOver,x[t],t][[1]]
Plot[x[t]/.sOver,{t,0,10}]

pUnder= {ω0->1,γ->1/4}
sUnder = DSolve[{de,x[0]==1,x'[0]==0}/.pUnder,x[t],t][[1]]
Plot[x[t]/.sUnder,{t,0,10}]

The homework asks about an overdamped oscillator and under what conditions you never cross zero.
Key insight: if x[t] is the sum of two exponentials, then the long time behavior is given by the slower decaying exponential.  So it will be necessary that the coefficient of that term is positive.  The remaining question is how negative the other term can be.  Here is a plot to play with:

Manipulate[Plot[α Exp[-2 t] + Exp[-t],{t,0,5}],{α,-5,5}]

But the main task today is to solve the undamped but nonlinear system of the good old pendulum.
The good news is that the solution has a name.

pendulum = θ''[t] + ω0^2 Sin[θ[t]] == 0

s=DSolve[pendulum,θ[t],t]

q[t_] = θ[t]/.s[[2]] /.{C[1]->A,C[2]->0,ω0->1}

Plot[q[t]/.A->0,{t,0,10}]

So how do we do the homework?!  Start with the known input energy:

E0 = (1-Cos[θ0])

Figure out how fast we are going when passing through angle θ

θdot = Sqrt[2(Cos[θ]-Cos[α])]

And integrate up all the dt’s where dt=dθ/(OverDot[θ])

T[θ0_] := 4*NIntegrate[1/Sqrt[2(Cos[θ]-Cos[θ0])],{θ,0,θ0}]

Here is the correction factor which we desire to expand in a series eventually.

f[α_] := T[α]/(2 π)

Plot[f[x],{x,0,π/2}]